aboutsummaryrefslogtreecommitdiffstats
path: root/pkgs/populate/rust.nix
blob: 4582532e12d78b4ca0fd2adea70baa6ef1ff0cd3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Populate's arguments, checked and as JSON, for the program in this
# directory, which delivers the sources.
{ coreutils, findutils, git, nix, openssh, pass, passage, program, rsync
, writers
}:

with import ../../lib;

let
  checks = import ./checks.nix;
in

{ backup ? false, force ? false, prune ? false, source, target }:
assert checks.checkTargetPath target.path;
assert all checks.checkSourceName (attrNames source);
assert checks.checkInputs source;
let
  # Store paths in the arguments stay dependencies of the script, so
  # building it builds them.
  spec = toJSON {
    version = 1;
    inherit backup force prune source;
    target = {
      inherit (target) host path;
      user = target.user or null;
      port = if target.port or null == null then null else toString target.port;
      sudo = target.sudo or false;
      extraOptions = target.extraOptions or [];
      # Decided during evaluation, like the other functions of krops do.
      local = isLocalTarget target;
    };
  };
in
writers.writeDash "populate.${target.host}" /* sh */ ''
  set -efu
  echo + "$0" >&2
  # The tools populate depends on, in front of others of the same name.
  PATH=${makeBinPath [
    coreutils findutils git nix openssh pass passage rsync
  ]}''${PATH:+:$PATH}
  export PATH
  # On a file descriptor of its own, so the commands populate runs keep
  # standard input.  The JSON is a single line, which can't be the delimiter.
  exec ${program}/bin/populate /dev/fd/3 3<<'EOF'
  ${spec}
  EOF
''