tv/3modules/x0vncserver.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

with import ./lib;
{ config, pkgs, ... }: let
  cfg = config.tv.x0vncserver;
in {
  options.tv.x0vncserver = {
    display = mkOption {
      default = ":${toString config.services.xserver.display}";
      type = types.str;
    };
    enable = mkEnableOption "tv.x0vncserver";
    pwfile = mkOption {
      default = toString <secrets> + "/vncpasswd";
      description = ''
        Use vncpasswd to edit pwfile.
        See: nix-shell -p tigervnc --run 'man vncpasswd'
      '';
      type = types.absolute-pathname;
    };
    rfbport = mkOption {
      default = 5900;
      type = types.int;
    };
    user = mkOption {
      default = config.krebs.build.user;
      type = types.user;
    };
  };
  config = mkIf cfg.enable {
    krebs.systemd.services.x0vncserver = {};
    systemd.services.x0vncserver = {
      after = [ "graphical.target" ];
      requires = [ "graphical.target" ];
      serviceConfig = {
        ExecStart = "${pkgs.tigervnc}/bin/x0vncserver ${toString [
          "-display ${cfg.display}"
          "-passwordfile \${CREDENTIALS_DIRECTORY}/pwfile"
          "-rfbport ${toString cfg.rfbport}"
        ]}";
        LoadCredential = "ssh_key:${cfg.pwfile}";
        User = cfg.user.name;
      };
    };
    tv.iptables.input-retiolum-accept-tcp = singleton (toString cfg.rfbport);
  };
}