aboutsummaryrefslogtreecommitdiffstats
path: root/src/Pager
diff options
context:
space:
mode:
Diffstat (limited to 'src/Pager')
-rw-r--r--src/Pager/Backend.hs43
-rw-r--r--src/Pager/Backend/Rivermonad.hs61
-rw-r--r--src/Pager/Backend/X11.hs129
3 files changed, 233 insertions, 0 deletions
diff --git a/src/Pager/Backend.hs b/src/Pager/Backend.hs
new file mode 100644
index 0000000..e126dcc
--- /dev/null
+++ b/src/Pager/Backend.hs
@@ -0,0 +1,43 @@
+-- | What the pager needs from a window manager.
+module Pager.Backend
+ ( Backend(..)
+ , getBackend
+ ) where
+
+import Data.Text (Text)
+import Pager.Types
+import qualified Pager.Backend.Rivermonad
+import qualified Pager.Backend.X11
+import qualified Rivermonad.Client
+
+
+data Backend = Backend
+ { getScreenGeometry :: IO Geometry
+ , getWorkspaces :: Geometry -> [Int] -> IO [Workspace]
+ -- ^ Screen geometry and the focused window of every workspace, as
+ -- given on the command line.
+ , viewWorkspace :: Text -> IO ()
+ , shiftWindowToWorkspace :: Int -> Text -> IO ()
+ }
+
+
+-- | rivermonad if its socket is there, EWMH on X11 otherwise. See
+-- 'Rivermonad.Client.selected'.
+getBackend :: IO Backend
+getBackend = do
+ rivermonad <- Rivermonad.Client.selected
+ return $
+ if rivermonad then
+ Backend
+ { getScreenGeometry = Pager.Backend.Rivermonad.getScreenGeometry
+ , getWorkspaces = Pager.Backend.Rivermonad.getWorkspaces
+ , viewWorkspace = Pager.Backend.Rivermonad.viewWorkspace
+ , shiftWindowToWorkspace = Pager.Backend.Rivermonad.shiftWindowToWorkspace
+ }
+ else
+ Backend
+ { getScreenGeometry = Pager.Backend.X11.getScreenGeometry
+ , getWorkspaces = Pager.Backend.X11.getWorkspaces
+ , viewWorkspace = Pager.Backend.X11.viewWorkspace
+ , shiftWindowToWorkspace = Pager.Backend.X11.shiftWindowToWorkspace
+ }
diff --git a/src/Pager/Backend/Rivermonad.hs b/src/Pager/Backend/Rivermonad.hs
new file mode 100644
index 0000000..b2d6365
--- /dev/null
+++ b/src/Pager/Backend/Rivermonad.hs
@@ -0,0 +1,61 @@
+-- | The pager on rivermonad (a window manager for the river Wayland
+-- compositor), over its IPC socket.
+module Pager.Backend.Rivermonad
+ ( getScreenGeometry
+ , getWorkspaces
+ , viewWorkspace
+ , shiftWindowToWorkspace
+ ) where
+
+import Data.Text (Text)
+import Pager.Types
+import qualified Data.List as List
+import qualified Rivermonad.Client as Client
+
+
+geometry :: Client.Rect -> Geometry
+geometry r =
+ Geometry
+ { geometry_x = Client.rect_x r
+ , geometry_y = Client.rect_y r
+ , geometry_width = Client.rect_width r
+ , geometry_height = Client.rect_height r
+ }
+
+getScreenGeometry :: IO Geometry
+getScreenGeometry =
+ geometry . Client.snapshot_screen <$> Client.getSnapshot
+
+-- The window manager knows which window every workspace focuses, so the
+-- window ids from the command line are not needed here.
+getWorkspaces :: Geometry -> [Int] -> IO [Workspace]
+getWorkspaces screenGeometry _focusWindows =
+ map workspace . Client.snapshot_workspaces <$> Client.getSnapshot
+ where
+ workspace ws =
+ Workspace
+ { workspace_geometry = screenGeometry
+ , workspace_focused = Client.workspace_focused ws
+ , workspace_name = Client.workspace_name ws
+ , workspace_windows =
+ uncurry (<>) $
+ List.partition window_focused $
+ map window (Client.workspace_windows ws)
+ }
+
+ window w =
+ Window
+ { window_id = Client.window_id w
+ , window_title = Client.window_title w
+ , window_geometry = geometry (Client.window_rect w)
+ , window_focused = Client.window_focused w
+ -- River cannot tell the window manager yet that a window wants
+ -- attention.
+ , window_urgent = False
+ }
+
+viewWorkspace :: Text -> IO ()
+viewWorkspace = Client.viewWorkspace
+
+shiftWindowToWorkspace :: Int -> Text -> IO ()
+shiftWindowToWorkspace = Client.shiftWindow
diff --git a/src/Pager/Backend/X11.hs b/src/Pager/Backend/X11.hs
new file mode 100644
index 0000000..9df5212
--- /dev/null
+++ b/src/Pager/Backend/X11.hs
@@ -0,0 +1,129 @@
+-- | The pager on an EWMH window manager on X11.
+module Pager.Backend.X11
+ ( getScreenGeometry
+ , getWorkspaces
+ , viewWorkspace
+ , shiftWindowToWorkspace
+ ) where
+
+import Data.Bits (testBit)
+import Data.Maybe (fromMaybe)
+import Data.Set (Set)
+import Data.Text (Text)
+import Pager.Types
+import qualified Data.List as List
+import qualified Data.Map as Map
+import qualified Data.Set as Set
+import qualified Data.Text as Text
+import qualified Graphics.X11 as X11
+import qualified Graphics.X11.EWMH as X11
+import qualified Graphics.X11.Extra as X11
+import qualified Graphics.X11.Xlib.Extras as X11
+
+
+getGeometry :: X11.Display -> X11.Window -> IO Geometry
+getGeometry d w = do
+ (_, x, y, width, height, _, _) <- X11.getGeometry d w
+ return Geometry
+ { geometry_x = fromIntegral x
+ , geometry_y = fromIntegral y
+ , geometry_width = fromIntegral width
+ , geometry_height = fromIntegral height
+ }
+
+getScreenGeometry :: IO Geometry
+getScreenGeometry =
+ X11.withDefaultDisplay $ \display ->
+ getGeometry display (X11.defaultRootWindow display)
+
+getWorkspaces :: Geometry -> [Int] -> IO [Workspace]
+getWorkspaces screenGeometry focusWindows =
+ X11.withDefaultDisplay $ \display ->
+ getWorkspaces' display screenGeometry (Set.fromList (map fromIntegral focusWindows))
+
+getWorkspaces' :: X11.Display -> Geometry -> Set X11.Window -> IO [Workspace]
+getWorkspaces' display screenGeometry focusWindows = do
+
+ let rootWindow = X11.defaultRootWindow display
+
+ currentDesktop <- fromMaybe 0 <$> X11.getCurrentDesktop display
+
+ workspaces <- do
+ names <- zip [0..] . fromMaybe [] <$> X11.getDesktopNames display
+ let
+ ws =
+ flip map names $ \(index, name) ->
+ Workspace
+ { workspace_geometry = screenGeometry
+ , workspace_focused = currentDesktop == index
+ , workspace_name = Text.pack name
+ , workspace_windows = []
+ }
+ return $ Map.fromList $ zip [0..] ws
+
+ clientList <-
+ maybe [] (map fromIntegral) <$>
+ X11.getWindowProperty32 display X11._NET_CLIENT_LIST rootWindow
+
+ let
+ f w = do
+ title <- X11.getWindowTitle display w
+ desktop <- fromMaybe 0 <$> X11.getWindowDesktop display w
+ geometry <- getGeometry display w
+
+ wm_hints <- X11.getWMHints display w
+
+ wm_state <-
+ maybe [] (map fromIntegral) <$>
+ X11.getWindowProperty32 display X11._NET_WM_STATE w
+
+ let urgent =
+ testBit (X11.wmh_flags wm_hints) X11.urgencyHintBit ||
+ elem X11._NET_WM_STATE_DEMANDS_ATTENTION wm_state
+
+ let
+ window =
+ Window
+ { window_id = fromIntegral w
+ , window_title = Text.pack $ fromMaybe "" title
+ , window_geometry = geometry
+ , window_focused = Set.member w focusWindows
+ , window_urgent = urgent
+ }
+
+ return ( window, desktop )
+
+ clientList' <- mapM f clientList
+
+ return
+ $ map (\ws -> ws { workspace_windows =
+ uncurry (<>) $
+ List.partition window_focused (workspace_windows ws)
+ })
+ $ Map.elems
+ $ foldr
+ (\(w, i) ->
+ Map.adjust (\ws -> ws { workspace_windows = w : workspace_windows ws })
+ i
+ )
+ workspaces
+ clientList'
+
+-- EWMH addresses desktops by index.
+withDesktopIndex :: Text -> (X11.Display -> Int -> IO ()) -> IO ()
+withDesktopIndex name f =
+ X11.withDefaultDisplay $ \display -> do
+ names <- fromMaybe [] <$> X11.getDesktopNames display
+ case Text.unpack name `List.elemIndex` names of
+ Just index -> f display index
+ Nothing -> fail $ "no such desktop: " <> show name
+
+viewWorkspace :: Text -> IO ()
+viewWorkspace name =
+ withDesktopIndex name $ \display index ->
+ X11.switchToDesktop display (fromIntegral index)
+
+shiftWindowToWorkspace :: Int -> Text -> IO ()
+shiftWindowToWorkspace window name =
+ withDesktopIndex name $ \display index ->
+ X11.moveWindowToDesktop display (fromIntegral window) (fromIntegral index)