krebs/5pkgs/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

with import <stockholm/lib>;

self: super:

# Import files and subdirectories like they are overlays.
foldl' mergeAttrs {}
  (map
    (name: import (./. + "/${name}") self super)
    (filter
      (name: name != "default.nix" && !hasPrefix "." name)
      (attrNames (readDir ./.))))

//

{
  ReaktorPlugins = self.callPackage ./simple/Reaktor/plugins.nix {};

  buildbot-full = self.callPackage ./simple/buildbot {
    plugins = with self.buildbot-plugins; [ www console-view waterfall-view ];
  };
  buildbot-worker = self.callPackage ./simple/buildbot/worker.nix {};

  # https://github.com/proot-me/PRoot/issues/106
  proot = self.writeDashBin "proot" ''
    export PROOT_NO_SECCOMP=1
    exec ${super.proot}/bin/proot "$@"
  '';

  # XXX symlinkJoin changed arguments somewhere around nixpkgs d541e0d
  symlinkJoin = { name, paths, ... }@args: let
    x = super.symlinkJoin args;
  in if typeOf x != "lambda" then x else super.symlinkJoin name paths;
}