Merge remote-tracking branch 'prism/master'

3 files changed, 321 insertions, 0 deletions

diff --git a/makefu/2configs/homeautomation/default.nix b/makefu/2configs/homeautomation/default.nix
new file mode 100644
index 000000000..596d0002a
--- /dev/null
+++ b/makefu/2configs/homeautomation/default.nix
@@ -0,0 +1,260 @@
+{ pkgs, lib, config, ... }:
+
+# Ideas:
+## wake-on-lan server
+## 
+let
+  tasmota_rgb = name: topic:
+# LED WS2812b
+#      effect_state_topic: "stat/led/Scheme"
+#      effect_command_topic: "cmnd/led/Scheme"
+#      effect_value_template: "{{ value_json.Scheme }}"
+  { platform = "mqtt";
+    inherit name;
+    retain = false;
+    qos = 1;
+    optimistic = false;
+    # state
+    # TODO: currently broken, will not use the custom state topic
+    #state_topic = "/ham/${topic}/stat/POWER";
+    state_topic = "/ham/${topic}/stat/POWER";
+    command_topic = "/ham/${topic}/cmnd/POWER";
+    availability_topic = "/ham/${topic}/tele/LWT";
+    payload_on= "ON";
+    payload_off= "OFF";
+    payload_available= "Online";
+    payload_not_available= "Offline";
+    # brightness
+    brightness_state_topic = "/ham/${topic}/stat/Dimmer";
+    brightness_command_topic = "/ham/${topic}/cmnd/Dimmer";
+    brightness_value_template = "{{ value_json.Dimmer }}";
+    brightness_scale = 100;
+    # color
+    rgb_state_topic = "/ham/${topic}/stat/Color";
+    rgb_command_topic = "/ham/${topic}/cmnd/MEM1"; # use enabled tasmota rule
+    rgb_command_mode = "hex";
+    rgb_command_template = "{{ '%02x%02x%02x' | format(red, green, blue)}}";
+    # effects
+    effect_state_topic = "/ham/${topic}/stat/Scheme";
+    effect_command_topic = "/ham/${topic}/cmnd/Scheme";
+    effect_value_template = "{{ value_json.Scheme }}";
+    effect_list = [ 0 1 2 3 4 5 6 7 8 9 10 11 12 ];
+};
+    # switchmode 1 - also toggle power
+    # switchtopic flurlicht
+    tasmota_motion = name: topic:
+    { platform = "mqtt";
+      device_class = "motion";
+      inherit name;
+      # TODO: currently broken, will not use the custom state topic
+      state_topic = "/ham/${topic}/stat/POWER";
+      payload_on = "ON";
+      payload_off = "OFF";
+      availability_topic = "/ham/${topic}/tele/LWT";
+      payload_available = "Online";
+      payload_not_available = "Offline";
+    };
+
+  firetv = "192.168.1.238";
+  tasmota_plug = name: topic:
+  { platform = "mqtt";
+    inherit name;
+    state_topic = "/ham/${topic}/stat/POWER1";
+    command_topic = "/ham/${topic}/cmnd/POWER1";
+    availability_topic = "/ham/${topic}/tele/LWT";
+    payload_on= "ON";
+    payload_off= "OFF";
+    payload_available= "Online";
+    payload_not_available= "Offline";
+  };
+  tasmota_bme = name: topic:
+  [ { platform = "mqtt";
+      name = "${name} Temperatur";
+      state_topic = "/ham/${topic}/tele/SENSOR";
+      value_template = "{{ value_json.BME280.Temperature }}";
+      unit_of_measurement = "°C";
+    }
+    { platform = "mqtt";
+      name = "${name} Luftfeuchtigkeit";
+      state_topic = "/ham/${topic}/tele/SENSOR";
+      value_template = "{{ value_json.BME280.Humidity }}";
+      unit_of_measurement = "%";
+    }
+    { platform = "mqtt";
+      name = "${name} Luftdruck";
+      state_topic = "/ham/${topic}/tele/SENSOR";
+      value_template = "{{ value_json.BME280.Pressure }}";
+      unit_of_measurement = "hPa";
+    }
+  ];
+  tasmota_am2301 = name: topic:
+  [ { platform = "mqtt";
+      name = "${name} Temperatur";
+      state_topic = "/ham/${topic}/tele/SENSOR";
+      value_template = "{{ value_json.AM2301.Temperature }}";
+      unit_of_measurement = "°C";
+    }
+    { platform = "mqtt";
+      name = "${name} Luftfeuchtigkeit";
+      state_topic = "/ham/${topic}/tele/SENSOR";
+      value_template = "{{ value_json.AM2301.Humidity }}";
+      unit_of_measurement = "%";
+    }
+  ];
+in {
+  imports = [
+    ./mqtt.nix
+  ];
+  #systemd.services.firetv = {
+  #  wantedBy = [ "multi-user.target" ];
+  #  serviceConfig = {
+  #    User = "nobody";
+  #    ExecStart = "${pkgs.python-firetv}/bin/firetv-server -d ${firetv}:5555";
+  #  };
+  #};
+  services.home-assistant = {
+    config = {
+      homeassistant = {
+        name = "Home"; time_zone = "Europe/Berlin";
+        latitude = "48.7687";
+        longitude = "9.2478";
+        elevation = 247;
+      };
+      #discovery = {};
+      conversation = {};
+      history = {};
+      logbook = {};
+      tts = [
+        { platform = "google";}
+      ];
+      sun.elevation = 247;
+      recorder = {};
+      media_player = [
+        { platform = "kodi";
+          host = firetv;
+        }
+        #{ platform = "firetv";
+        #  # assumes python-firetv running
+        #}
+      ];
+      mqtt = {
+        broker = "localhost";
+        port = 1883;
+        client_id = "home-assistant";
+        username = "hass";
+        password = lib.removeSuffix "\n" (builtins.readFile <secrets/mqtt/hass>);
+        keepalive = 60;
+        protocol = 3.1;
+        birth_message = {
+          topic = "/ham/hass/tele/LWT";
+          payload = "Online";
+          qos = 1;
+          retain = true;
+        };
+        will_message = {
+          topic = "/ham/hass/tele/LWT";
+          payload = "Offline";
+          qos = 1;
+          retain = true;
+        };
+      };
+      binary_sensor = [
+        (tasmota_motion "Flur Bewegung" "flurlicht")
+      ];
+      sensor = [
+        # broken
+        #{ platform = "speedtest";
+        #  monitored_conditions = [ "ping" "download" "upload" ];
+        #}
+        { platform = "luftdaten";
+          name = "Wangen";
+          sensorid = "663";
+          monitored_conditions = [ "P1" "P2" ];
+        }
+        # https://www.home-assistant.io/cookbook/automation_for_rainy_days/
+        { platform = "darksky";
+          api_key = lib.removeSuffix "\n"
+            (builtins.readFile <secrets/hass/darksky.apikey>);
+          language = "de";
+          monitored_conditions = [ "summary" "icon"
+          "nearest_storm_distance" "precip_probability"
+          "precip_intensity"
+          "temperature"
+          "apparent_temperature"
+          "hourly_summary"
+          "humidity"
+          "pressure"
+          "uv_index" ];
+          units =  "si" ;
+          update_interval = {
+                days = 0;
+                hours = 0;
+                minutes = 30;
+                seconds = 0;
+          };
+        }
+      ]
+      ++ (tasmota_bme "Schlafzimmer" "schlafzimmer")
+      ++ (tasmota_am2301 "Arbeitszimmer" "arbeitszimmer");
+      frontend = { };
+      group =
+        { default_view =
+          { view = "yes";
+            entities = [
+              "group.flur"
+              "group.schlafzimmer"
+              "group.draussen"
+              "group.wohnzimmer"
+              "group.arbeitszimmer"
+            ];
+          };
+          flur = [
+            "light.flurlicht"
+            "binary_sensor.flur_bewegung"
+          ];
+          wohnzimmer = [
+            "media_player.kodi"
+          ];
+          draussen = [
+            "sensor.dark_sky_temperature"
+            "sensor.dark_sky_hourly_summary"
+            "sensor.wangen_pm10"
+            "sensor.wangen_pm25"
+          ];
+          schlafzimmer = [
+            "sensor.schlafzimmer_temperatur"
+            "sensor.schlafzimmer_luftdruck"
+            "sensor.schlafzimmer_luftfeuchtigkeit"
+            "switch.lichterkette_schlafzimmer"
+          ];
+          arbeitszimmer = [
+            "switch.strom_staubsauger"
+            "sensor.arbeitszimmer_temperatur"
+            "sensor.arbeitszimmer_luftfeuchtigkeit"
+          ];
+        };
+      http = { };
+      switch = [
+        (tasmota_plug "Lichterkette Schlafzimmer" "schlafzimmer")
+        (tasmota_plug "Strom Staubsauger" "arbeitszimmer")
+      ];
+      light = [ (tasmota_rgb "Flurlicht" "flurlicht" ) ];
+      automation = [
+        { alias = "Staubsauger Strom aus nach 6h";
+          trigger = {
+            platform = "state";
+            entity_id = "switch.strom_staubsauger";
+            to = "on";
+            for.hours = 6;
+          };
+          action = {
+            service= "homeassistant.turn_off";
+            entity_id= "switch.strom_staubsauger";
+          };
+        }
+      ];
+    };
+    enable = true;
+    #configDir = "/var/lib/hass";
+  };
+}
diff --git a/makefu/2configs/homeautomation/google-muell.nix b/makefu/2configs/homeautomation/google-muell.nix
new file mode 100644
index 000000000..235cc1546
--- /dev/null
+++ b/makefu/2configs/homeautomation/google-muell.nix
@@ -0,0 +1,37 @@
+{ config, lib, pkgs, buildPythonPackage, ... }:
+with import <stockholm/lib>;
+let
+  pkg = pkgs.ampel;
+  home = "/var/lib/ampel";
+  sec = "${toString <secrets>}/google-muell.json";
+  ampelsec = "${home}/google-muell.json";
+  cred = "${toString <secrets>}/google-muell-creds.json";
+  # TODO: generate this credential file locally
+  ampelcred = "${home}/google-muell-creds.json";
+  esp = "192.168.8.204";
+  sleepval = "1800";
+in {
+  users.users.ampel = {
+    uid = genid "ampel";
+    createHome = true;
+    isSystemUser = true;
+    inherit home;
+  };
+  systemd.services.google-muell-ampel = {
+    description = "Send led change to rgb cubes";
+    after = [ "network-online.target"  ];
+    wantedBy = [ "multi-user.target"  ];
+    serviceConfig = {
+      User = "ampel";
+      ExecStartPre = pkgs.writeDash "copy-ampel-secrets" ''
+        install -m600 -o ampel ${sec} ${ampelsec}
+        install -m600 -o ampel ${cred} ${ampelcred}
+      '';
+      ExecStart = "${pkg}/bin/google-muell --esp=${esp} --client-secrets=${ampelsec} --credential-path=${ampelcred} --sleepval=${sleepval}";
+      PermissionsStartOnly = true;
+      Restart = "always";
+      RestartSec = 10;
+      PrivateTmp = true;
+    };
+  };
+}
diff --git a/makefu/2configs/homeautomation/mqtt.nix b/makefu/2configs/homeautomation/mqtt.nix
new file mode 100644
index 000000000..cd1c328d7
--- /dev/null
+++ b/makefu/2configs/homeautomation/mqtt.nix
@@ -0,0 +1,24 @@
+{ pkgs, config, ... }:
+{
+  services.mosquitto = {
+    enable = true;
+    host = "0.0.0.0";
+    allowAnonymous = false;
+    checkPasswords = true;
+    # see <host>/mosquitto
+    users.sensor = {
+      hashedPassword = "$6$2DXU7W1bvqXPqxkF$vtdz5KTd/T09hmoc9LjgEGFjvpwQbQth6vlVcr5hJNLgcBHv4U03YCKC8TKXbmQAa8xiJ76xJIg25kcL+KI3tg==";
+      acl = [ "topic readwrite #" ];
+    };
+    users.hass = {
+      hashedPassword = "$6$SHuYGrE5kPSUc/hu$EomZ0KBy+vkxLt/6eJkrSBjYblCCeMjhDfUd2mwqXYJ4XsP8hGmZ59mMlmBCd3AvlFYQxb4DT/j3TYlrqo7cDA==";
+      acl = [ "topic readwrite #" ];
+    };
+    users.stats = {
+      hashedPassword = "$6$j4H7KXD/YZgvgNmL$8e9sUKRXowDqJLOVgzCdDrvDE3+4dGgU6AngfAeN/rleGOgaMhee2Mbg2KS5TC1TOW3tYbk9NhjLYtjBgfRkoA==";
+      acl = [ "topic read #" ];
+    };
+  };
+  environment.systemPackages = [ pkgs.mosquitto ];
+  # port open via trusted interface
+}