l: use new xserver architecture

4 files changed, 258 insertions, 29 deletions

diff --git a/lass/2configs/baseX.nix b/lass/2configs/baseX.nix
index e373c3d9a..4e46c18d2 100644
--- a/lass/2configs/baseX.nix
+++ b/lass/2configs/baseX.nix
@@ -5,7 +5,8 @@ let
 in {
   imports = [
     ./base.nix
-    ./urxvt.nix
+    #./urxvt.nix
+    ./xserver
   ];
 
   users.extraUsers.mainUser.extraGroups = [ "audio" ];
@@ -37,36 +38,36 @@ in {
     zathura
 
   #window manager stuff
-    haskellPackages.xmobar
-    haskellPackages.yeganesh
-    dmenu2
-    xlibs.fontschumachermisc
+    #haskellPackages.xmobar
+    #haskellPackages.yeganesh
+    #dmenu2
+    #xlibs.fontschumachermisc
   ];
 
-  fonts.fonts = [
-    pkgs.xlibs.fontschumachermisc
-  ];
-
-  services.xserver = {
-    enable = true;
-
-    windowManager.xmonad.extraPackages = hspkgs: with hspkgs; [
-      X11-xshape
-    ];
-    windowManager.xmonad.enable = true;
-    windowManager.xmonad.enableContribAndExtras = true;
-    windowManager.default = "xmonad";
-    desktopManager.default = "none";
-    desktopManager.xterm.enable = false;
-    displayManager.slim.enable = true;
-    displayManager.auto.enable = true;
-    displayManager.auto.user = mainUser.name;
-
-    layout = "us";
-    xkbModel = "evdev";
-    xkbVariant = "altgr-intl";
-    xkbOptions = "caps:backspace";
-  };
+  #fonts.fonts = [
+  #  pkgs.xlibs.fontschumachermisc
+  #];
+
+  #services.xserver = {
+  #  enable = true;
+
+  #  windowManager.xmonad.extraPackages = hspkgs: with hspkgs; [
+  #    X11-xshape
+  #  ];
+  #  windowManager.xmonad.enable = true;
+  #  windowManager.xmonad.enableContribAndExtras = true;
+  #  windowManager.default = "xmonad";
+  #  desktopManager.default = "none";
+  #  desktopManager.xterm.enable = false;
+  #  displayManager.slim.enable = true;
+  #  displayManager.auto.enable = true;
+  #  displayManager.auto.user = mainUser.name;
+
+  #  layout = "us";
+  #  xkbModel = "evdev";
+  #  xkbVariant = "altgr-intl";
+  #  xkbOptions = "caps:backspace";
+  #};
 
   services.logind.extraConfig = ''
     HandleLidSwitch=ignore
diff --git a/lass/2configs/xserver/Xresources.nix b/lass/2configs/xserver/Xresources.nix
new file mode 100644
index 000000000..d52418897
--- /dev/null
+++ b/lass/2configs/xserver/Xresources.nix
@@ -0,0 +1,27 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+pkgs.writeText "Xresources" ''
+  URxvt*scrollBar:                      false
+  URxvt*urgentOnBell:                   true
+  URxvt*font:                           -*-clean-*-*-*-*-*-*-*-*-*-*-iso10646-*
+  URxvt*boldFont:                       -*-clean-*-*-*-*-*-*-*-*-*-*-iso10646-*
+
+  ! ref https://github.com/muennich/urxvt-perls
+  URxvt.perl-lib: ${pkgs.urxvt_perls}/lib/urxvt/perl
+  URxvt.perl-ext-common:      default,clipboard,url-select,keyboard-select
+  URxvt.url-select.launcher:  browser-select
+  URxvt.url-select.underline: true
+  URxvt.keysym.M-u:           perl:url-select:select_next
+  URxvt.keysym.M-Escape:      perl:keyboard-select:activate
+  URxvt.keysym.M-s:           perl:keyboard-select:search
+
+  URxvt.intensityStyles: false
+
+  URxvt*background:                     #000000
+  URxvt*foreground:                     #ffffff
+
+  !change unreadable blue
+  URxvt*color4:                         #268bd2
+''
diff --git a/lass/2configs/xserver/default.nix b/lass/2configs/xserver/default.nix
new file mode 100644
index 000000000..ceccf5fee
--- /dev/null
+++ b/lass/2configs/xserver/default.nix
@@ -0,0 +1,161 @@
+{ config, lib, pkgs, ... }@args:
+
+with lib;
+
+let
+  # TODO krebs.build.user
+  user = config.users.users.mainUser;
+
+  out = {
+
+    services.xserver = {
+      display = 11;
+      tty = 11;
+
+      synaptics = {
+        enable = true;
+        twoFingerScroll = true;
+        accelFactor = "0.035";
+      };
+
+      #keyboard stuff
+      layout = "us";
+      xkbVariant = "altgr-intl";
+      xkbOptions = "caps:backspace";
+    };
+
+    fonts.fonts = [
+      pkgs.xlibs.fontschumachermisc
+    ];
+
+    systemd.services.urxvtd = {
+      wantedBy = [ "multi-user.target" ];
+      reloadIfChanged = true;
+      serviceConfig = {
+        ExecReload = need-reload "urxvtd.service";
+        ExecStart = "${pkgs.rxvt_unicode}/bin/urxvtd";
+        Restart = "always";
+        RestartSec = "2s";
+        StartLimitBurst = 0;
+        User = user.name;
+      };
+    };
+
+    environment.systemPackages = [
+      pkgs.gitAndTools.qgit
+      pkgs.mpv
+      pkgs.pavucontrol
+      pkgs.slock
+      pkgs.sxiv
+      pkgs.xsel
+      pkgs.zathura
+    ];
+
+    security.setuidPrograms = [
+      "slock"
+    ];
+
+    systemd.services.display-manager = mkForce {};
+
+    services.xserver.enable = true;
+
+    systemd.services.xmonad = {
+      wantedBy = [ "multi-user.target" ];
+      requires = [ "xserver.service" ];
+      environment = xmonad-environment;
+      serviceConfig = {
+        ExecStart = "${xmonad-start}/bin/xmonad";
+        ExecStop = "${xmonad-stop}/bin/xmonad-stop";
+        User = user.name;
+        WorkingDirectory = user.home;
+      };
+    };
+
+    systemd.services.xserver = {
+      after = [
+        "systemd-udev-settle.service"
+        "local-fs.target"
+        "acpid.service"
+      ];
+      reloadIfChanged = true;
+      environment = xserver-environment;
+      serviceConfig = {
+        ExecReload = need-reload "xserver.service";
+        ExecStart = "${xserver}/bin/xserver";
+      };
+    };
+  };
+
+  xmonad-environment = {
+    DISPLAY = ":${toString config.services.xserver.display}";
+    XMONAD_STATE = "/tmp/xmonad.state";
+
+    # XXX JSON is close enough :)
+    XMONAD_WORKSPACES0_FILE = pkgs.writeText "xmonad.workspaces0" (toJSON [
+      "cr"
+      "gm"
+      "ff"
+      "IM"
+      "mail"
+      "stockholm"
+    ]);
+  };
+
+  xmonad-start = pkgs.writeScriptBin "xmonad" ''
+    #! ${pkgs.bash}/bin/bash
+    set -efu
+    export PATH; PATH=${makeSearchPath "bin" ([
+      pkgs.rxvt_unicode
+      pkgs.i3lock
+      pkgs.haskellPackages.yeganesh
+      pkgs.haskellPackages.xmobar
+      pkgs.dmenu
+    ] ++ config.environment.systemPackages)}:/var/setuid-wrappers
+    settle() {(
+      # Use PATH for a clean journal
+      command=''${1##*/}
+      PATH=''${1%/*}; export PATH
+      shift
+      until "$command" "$@"; do
+        ${pkgs.coreutils}/bin/sleep 1
+      done
+    )&}
+    settle ${pkgs.xorg.xhost}/bin/xhost +LOCAL:
+    settle ${pkgs.xorg.xrdb}/bin/xrdb -merge ${import ./Xresources.nix args}
+    settle ${pkgs.xorg.xsetroot}/bin/xsetroot -solid '#1c1c1c'
+    exec ${pkgs.xmonad-lass}/bin/xmonad
+  '';
+
+  xmonad-stop = pkgs.writeScriptBin "xmonad-stop" ''
+    #! /bin/sh
+    exec ${pkgs.xmonad-lass}/bin/xmonad --shutdown
+  '';
+
+  xserver-environment = {
+    XKB_BINDIR = "${pkgs.xorg.xkbcomp}/bin"; # Needed for the Xkb extension.
+    XORG_DRI_DRIVER_PATH = "/run/opengl-driver/lib/dri"; # !!! Depends on the driver selected at runtime.
+    LD_LIBRARY_PATH = concatStringsSep ":" (
+      [ "${pkgs.xorg.libX11}/lib" "${pkgs.xorg.libXext}/lib" ]
+      ++ concatLists (catAttrs "libPath" config.services.xserver.drivers));
+  };
+
+  xserver = pkgs.writeScriptBin "xserver" ''
+    #! /bin/sh
+    set -efu
+    exec ${pkgs.xorg.xorgserver}/bin/X \
+        :${toString config.services.xserver.display} \
+        vt${toString config.services.xserver.tty} \
+        -config ${import ./xserver.conf.nix args} \
+        -logfile /var/log/X.${toString config.services.xserver.display}.log \
+        -nolisten tcp \
+        -xkbdir ${pkgs.xkeyboard_config}/etc/X11/xkb \
+  '';
+
+  need-reload = s: let
+    pkg = pkgs.writeScriptBin "need-reload" ''
+      #! /bin/sh
+      echo "$*"
+    '';
+  in "${pkg}/bin/need-reload ${s}";
+
+in out
diff --git a/lass/2configs/xserver/xserver.conf.nix b/lass/2configs/xserver/xserver.conf.nix
new file mode 100644
index 000000000..e8a997a99
--- /dev/null
+++ b/lass/2configs/xserver/xserver.conf.nix
@@ -0,0 +1,40 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.services.xserver;
+in
+
+pkgs.stdenv.mkDerivation {
+  name = "xserver.conf";
+
+  xfs = optionalString (cfg.useXFS != false)
+    ''FontPath "${toString cfg.useXFS}"'';
+
+  inherit (cfg) config;
+
+  buildCommand =
+    ''
+      echo 'Section "Files"' >> $out
+      echo $xfs >> $out
+
+      for i in ${toString config.fonts.fonts}; do
+        if test "''${i:0:''${#NIX_STORE}}" == "$NIX_STORE"; then
+          for j in $(find $i -name fonts.dir); do
+            echo "  FontPath \"$(dirname $j)\"" >> $out
+          done
+        fi
+      done
+
+      for i in $(find ${toString cfg.modules} -type d); do
+        if test $(echo $i/*.so* | wc -w) -ne 0; then
+          echo "  ModulePath \"$i\"" >> $out
+        fi
+      done
+
+      echo 'EndSection' >> $out
+
+      echo "$config" >> $out
+    '';
+}